[minin]

Сообщение от The Godfather

Ну во-первых, есть такая полезная вещь как ИБП - и правда полезная
Во-вторых - у вас так часто питание отключают?

А если свет на пару часов выключат. Я на работе. Интернет соседям раздать надо (когда свет включат).

В-третьих, в батнике можно создать паузу - гугл в помощь

Спасибо. Погуглил написал батник.

Спойлер:

@echo off
echo %date% %time% --- STARTED --- >> pinger.log

set Try=1
rem таймаут пинга в мс
set TimeOut=10000
rem количество попыток пинга
set MaxPing=3
rem пауза в с
set Pause=60
set Pause2=3
rem адрес хоста для пинга
set host=ya.ru

:start
echo.
echo start ping
ping %host% -n 1 -w %TimeOut%
echo.
echo %errorlevel%
if errorlevel=1 goto ping
goto ok

:ping
ping %host% -n 1 -w %TimeOut%
if not errorlevel=1 goto ok
set /a Try=%Try%+1
ping localhost -n %Pause2% > nul
if %Try% geq %MaxPing% goto bad

goto ping

:ok
echo.
echo ALL RIGHT
ping localhost -n %Pause% > nul
goto end

:bad
set /a Try=1
echo.
echo BAD CONNECT
echo %date% %time% --! Trouble, reconnect !-- >> pinger.log
ipconfig /renew
goto start

:end
set /a Try=1
echo.
goto start

вроде работает